10ge2p1x710-ethip4ipsec1tnlhw-ip4base-int-aes128gcm-ndrpdr.robot revision fcc77752
1# Copyright (c) 2019 Cisco and/or its affiliates.
2# Licensed under the Apache License, Version 2.0 (the "License");
3# you may not use this file except in compliance with the License.
4# You may obtain a copy of the License at:
5#
6#     http://www.apache.org/licenses/LICENSE-2.0
7#
8# Unless required by applicable law or agreed to in writing, software
9# distributed under the License is distributed on an "AS IS" BASIS,
10# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
11# See the License for the specific language governing permissions and
12# limitations under the License.
13
14*** Settings ***
15| Resource | resources/libraries/robot/shared/default.robot
16| Resource | resources/libraries/robot/crypto/ipsec.robot
17| ...
18| Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR | TNL_1
19| ... | IP4FWD | IPSEC | IPSECHW | IPSECINT | NIC_Intel-X710 | BASE
20| ... | AES_128_GCM | AES
21| ...
22| Suite Setup | Setup suite single link | performance | ipsechw
23| Suite Teardown | Tear down suite | performance
24| Test Setup | Setup test
25| Test Teardown | Tear down test | performance
26| ...
27| Test Template | Local Template
28| ...
29| Documentation | *RFC2544: Pkt throughput IPv4 IPsec tunnel mode.*
30| ...
31| ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
32| ... | with single links between nodes.
33| ... | *[Enc] Packet Encapsulations:* Eth-IPv4 on TG-DUTn,
34| ... | Eth-IPv4-IPSec on DUT1-DUT2
35| ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with multiple
36| ... | IPsec tunnels between them. DUTs get IPv4 traffic from TG, encrypt it
37| ... | and send to another DUT, where packets are decrypted and sent back to TG
38| ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
39| ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
40| ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
41| ... | of packets transmitted. NDR and PDR are discovered for different\
42| ... | Ethernet L2 frame sizes using MLRsearch library.\
43| ... | Test packets are generated by TG on
44| ... | links to DUTs. TG traffic profile contains two L3 flow-groups
45| ... | (flow-group per direction, number of flows per flow-group equals to
46| ... | number of IPSec tunnels) with all packets
47| ... | containing Ethernet header, IPv4 header with IP protocol=61 and
48| ... | static payload. MAC addresses are matching MAC addresses of the TG
49| ... | node interfaces. Incrementing of IP.dst (IPv4 destination address) field
50| ... | is applied to both streams.
51| ... | *[Ref] Applicable standard specifications:* RFC4303 and RFC2544.
52
53*** Variables ***
54| @{plugins_to_enable}= | dpdk_plugin.so | crypto_ia32_plugin.so
55| ... | crypto_ipsecmb_plugin.so | crypto_openssl_plugin.so
56| ${osi_layer}= | L3
57| ${crypto_type}= | HW_DH895xcc
58| ${nic_name}= | Intel-X710
59| ${nic_driver}= | vfio-pci
60| ${overhead}= | ${54}
61| ${tg_if1_ip4}= | 192.168.10.2
62| ${dut1_if1_ip4}= | 192.168.10.1
63| ${dut1_if2_ip4}= | 100.0.0.1
64| ${dut2_if1_ip4}= | 200.0.0.2
65| ${dut2_if2_ip4}= | 192.168.20.1
66| ${tg_if2_ip4}= | 192.168.20.2
67| ${raddr_ip4}= | 20.0.0.0
68| ${laddr_ip4}= | 10.0.0.0
69| ${addr_range}= | ${24}
70| ${n_tunnels}= | ${1}
71# Traffic profile:
72| ${traffic_profile}= | trex-sl-3n-ethip4-ip4dst${n_tunnels}
73
74*** Keywords ***
75| Local Template
76| | [Documentation]
77| | ... | [Cfg] DUT runs IPSec tunneling AES_128_GCM config.
78| | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
79| | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
80| | ...
81| | ... | *Arguments:*
82| | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
83| | ... | Type: integer, string
84| | ... | - phy_cores - Number of physical cores. Type: integer
85| | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
86| | ...
87| | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
88| | ...
89| | Set Test Variable | \${frame_size}
90| | ...
91| | # These are enums (not strings) so they cannot be in Variables table.
92| | ${encr_alg}= | Crypto Alg AES GCM 128
93| | ${auth_alg}= | Set Variable | ${NONE}
94| | ${ipsec_proto}= | IPsec Proto ESP
95| | ...
96| | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
97| | And Add PCI devices to all DUTs
98| | And Set Max Rate And Jumbo And Handle Multi Seg
99| | And Add cryptodev to all DUTs | ${phy_cores}
100| | And Apply startup configuration on all VPP DUTs
101| | And VPP IPsec Select Backend | ${dut1} | ${ipsec_proto} | index=${1}
102| | And VPP IPsec Select Backend | ${dut2} | ${ipsec_proto} | index=${1}
103| | When Initialize layer driver | ${nic_driver}
104| | And Initialize IPSec in 3-node circular topology
105| | And VPP IPsec Create Tunnel Interfaces
106| | ... | ${nodes} | ${dut1_if2_ip4} | ${dut2_if1_ip4} | ${dut1_if2}
107| | ... | ${dut2_if1} | ${n_tunnels} | ${encr_alg} | ${auth_alg}
108| | ... | ${laddr_ip4} | ${raddr_ip4} | ${addr_range}
109| | Then Find NDR and PDR intervals using optimized search
110
111*** Test Cases ***
112| tc01-64B-1c-ethip4ipsec1tnlhw-ip4base-int-aes128gcm-ndrpdr
113| | [Tags] | 64B | 1C
114| | frame_size=${64} | phy_cores=${1}
115
116| tc02-64B-2c-ethip4ipsec1tnlhw-ip4base-int-aes128gcm-ndrpdr
117| | [Tags] | 64B | 2C
118| | frame_size=${64} | phy_cores=${2}
119
120| tc03-64B-4c-ethip4ipsec1tnlhw-ip4base-int-aes128gcm-ndrpdr
121| | [Tags] | 64B | 4C
122| | frame_size=${64} | phy_cores=${4}
123
124| tc04-1518B-1c-ethip4ipsec1tnlhw-ip4base-int-aes128gcm-ndrpdr
125| | [Tags] | 1518B | 1C
126| | frame_size=${1518} | phy_cores=${1}
127
128| tc05-1518B-2c-ethip4ipsec1tnlhw-ip4base-int-aes128gcm-ndrpdr
129| | [Tags] | 1518B | 2C
130| | frame_size=${1518} | phy_cores=${2}
131
132| tc06-1518B-4c-ethip4ipsec1tnlhw-ip4base-int-aes128gcm-ndrpdr
133| | [Tags] | 1518B | 4C
134| | frame_size=${1518} | phy_cores=${4}
135
136| tc10-IMIX-1c-ethip4ipsec1tnlhw-ip4base-int-aes128gcm-ndrpdr
137| | [Tags] | IMIX | 1C
138| | frame_size=IMIX_v4_1 | phy_cores=${1}
139
140| tc11-IMIX-2c-ethip4ipsec1tnlhw-ip4base-int-aes128gcm-ndrpdr
141| | [Tags] | IMIX | 2C
142| | frame_size=IMIX_v4_1 | phy_cores=${2}
143
144| tc12-IMIX-4c-ethip4ipsec1tnlhw-ip4base-int-aes128gcm-ndrpdr
145| | [Tags] | IMIX | 4C
146| | frame_size=IMIX_v4_1 | phy_cores=${4}
147